Page 1 sur 1

[RÉSOLU] Requête Overpass pour récupérer limite d'un arrondissement?

Publié : ven. août 18, 2017 6:42 pm
par Winfried
Bonjour,

J'ai beau chercher dans Google, je n'arrive pas à trouver la requête pour récupérer la limite administrative d'un arrondissement (à Paris).

Merci.

Re: Requête Overpass pour récupérer limite d'un arrondissement?

Publié : ven. août 18, 2017 7:14 pm
par OsmO
Un arrondissement est défini par une relation, par exemple relation 20727 pour le 1er arrondissement de Paris.

Tu peux la récupérer avec une requête du type :

Code : Tout sélectionner

[out:json][timeout:25];
(
  relation(20727);
);
out body;
>;
out skel qt;

Re: Requête Overpass pour récupérer limite d'un arrondissement?

Publié : ven. août 18, 2017 7:23 pm
par Winfried
Merci.

Comment trouver le numéro de la relation d'un arrondissement donné?

Re: Requête Overpass pour récupérer limite d'un arrondissement?

Publié : ven. août 18, 2017 7:56 pm
par OsmO
Sur le site osm.org, recherche par exemple "paris 2e arrondissement" et dans la liste des résultats tu verras qu'il s'agit de la relation 9542.

Re: Requête Overpass pour récupérer limite d'un arrondissement?

Publié : ven. août 18, 2017 8:04 pm
par Winfried
Merci.

Je n'ai pas trouvé quelle requête OT en QL utiliser pour limiter la recherche dans un arrondissement : il ne retourne rien.

Code : Tout sélectionner

[out:json][timeout:25];

relation(36000020727)->.searchArea;
(
  way["amenity"="bicycle_parking"](area.searchArea);
  node["amenity"="bicycle_parking"](area.searchArea);
);

out center;
D'ailleurs, d'où vient ce chiffre magique de 3.600.000.000 ?

---
Edit : la solution

Code : Tout sélectionner

[out:json][timeout:25];

//Paris = 7444
rel(7444);map_to_area -> .searchArea;

(
node["key"="value"](area.searchArea);
way["key"="value"](area.searchArea);
relation["key"="value"](area.searchArea);
);

out body;
>;
out skel qt;
Merci.

Re: [RÉSOLU] Requête Overpass pour récupérer limite d'un arrondissement?

Publié : sam. août 19, 2017 8:56 am
par Winfried
Par contre, la requête fonctionne par le web, mais plante quand exécutée dans JOSM : quelqu'un a une idée?

Code : Tout sélectionner

//20727 = 1er arrdt Paris
rel(20727);map_to_area -> .searchArea;

(
node["highway"="traffic_signals"](area.searchArea);
way["highway"="traffic_signals"](area.searchArea);
relation["highway"="traffic_signals"](area.searchArea);
);

out body;
>;
out skel qt;
JOSM.rel.query.fails.png
JOSM.rel.query.fails.png (12.84 Kio) Consulté 4610 fois

Re: [RÉSOLU] Requête Overpass pour récupérer limite d'un arrondissement?

Publié : sam. août 19, 2017 9:13 am
par cquest
JOSM attend du XML avec les metadonnées...

ajouter: [out:xml] au début

et remplacer les "out" par "out meta"

On peut aussi directement chercher la relation en passant son nom, exemple: http://overpass-turbo.eu/s/r4I

Code : Tout sélectionner

[out:xml][timeout:25];
{{geocodeArea:"Paris 2e arrondissement"}}->.searchArea;
(
  node["amenity"="bicycle_parking"](area.searchArea);
  way["amenity"="bicycle_parking"](area.searchArea);
  relation["amenity"="bicycle_parking"](area.searchArea);
);
out meta;
>;
out meta;

Re: [RÉSOLU] Requête Overpass pour récupérer limite d'un arrondissement?

Publié : sam. août 19, 2017 11:08 am
par Winfried
Merci :)